# Tax Incidence in a Competitive Industry

This set of exercises uses the same demand and supply specification as 
the previous one.

kill(all)$  fpprintprec : 5$
DQ(p, a, ED) := a*p^ED$   DP(q,a,ED) := (q/a)^(1/ED)$
SQ(p, b, ES) := b*p^ES$   SP(q,b,ES) := (q/b)^(1/ES)$

For reference below, determine the equilibrium quantity and price, using
find_root( ), for the following parameter values: 
[a0,ED0,b0,ES0] : [1200,-4,40,0.75].

/*Input. Execute (ctrl-enter) for results */
[a0, ED0, b0, ES0] : [1200, -4, 40, 0.75]$
qE : find_root(DP(q, a0, ED0) - 
    SP(q, b0, ES0) = 0, q, 0.01, 500 )$
pE : find_root(DQ(p, a0, ED0) - 
    SQ(p, b0, ES0) = 0, p, 0.01, 500 )$
[qE, pE];

## Review: The Excise Tax

Confirm that the  results of an excise tax, X0 = 0.50 are as follows:
the quantity traded falls from 68.437 units to 57.82 units, the price
paid by buyers rises from 2.0463 to 2.1344, and the price
received by sellers falls from 2.0463 to 1.6344. 

/*Input. Execute (ctrl-enter) for results */
X0 : 0.5$
qX0 : find_root(DP(q, a0, ED0) = 
     SP(q, b0, ES0) + X0, q, 0.01, 500 )$
pDX0 : DP(qX0, a0, ED0 )$
pSX0 : SP(qX0, b0, ES0)$
[qX0, pDX0, pSX0];  [pDX0 - pE, pSX0 - pE];

Draw a graph that shows these results

/*Input. Execute (ctrl-enter) for results */
/* Logical expressions used to indicate prices
   and quantties.
*/
pGrossNew : if q < qX0 then pDX0 else 0$
pNetNew: if q < qX0 then pSX0 else 0$
/* The graph
*/
wxdraw2d( user_preamble = "set key bottom right", 
 xlabel = "Quantity",  ylabel = "$ per unit",
 yrange = [0, 1.25*pDX0], line_type=dots,
 explicit(pGrossNew, q, 0, 1.25*qE),
 explicit(pNetNew, q, 0, 1.25*qE), 
 line_type=solid, line_width=2, 
 key = "Demand",explicit(DP(q,a0,ED0),q,0,1.25*qE), 
 color = red , key = "Initial Supply", 
 explicit(SP(q, b0, ES0), q, 0, 1.25*qE), 
 color=orange, key="Tax-laden Supply",
 explicit(X0 + SP(q, b0, ES0), q, 0, 1.25*qE))$

## The Ad valorem Tax

An excise tax is based on the number of units sold; an ad valorem tax
is based on the value of the sale. Impose a 40% tax rate, V0 = 0.4 on
the buyers. 

The tax-laden price is (1 + V0) times the pre-tax price. As a result 
the amount that buyers are willing and able to pay to sellers equals 
DP(q, a0, ED0)/(1 + V0). 

Confirm the following: the quantity traded falls to 55.335, the tax-inclusive 
price rises to 2.1580, and the net price (received by sellers) falls to 
1.5414. 

/*Input. Execute (ctrl-enter) for results */
V0 : 0.40$
qV0 : find_root(DP(q, a0, ED0)/(1 + V0) = 
     SP(q, b0, ES0), q, 0.01, 500 )$
pDV0 : DP(qV0, a0, ED0 )$
pSV0 : SP(qV0, b0, ES0)$
[qV0, pDV0, pSV0]; [pDV0 - pE, pSV0 - pE];

Create a new pair of logical expressions that can be used to 
show the prices and the relevant, post-tax quantity in a graph.

/*Input. Execute (ctrl-enter) for results */
pNewGross : if q < qV0 then pDV0 else 0$
pNewNet : if q < qV0 then pDV0/(1+V0) else 0$

Draw the graph.

/*Input. Execute (ctrl-enter) for results */
wxdraw2d(  yrange = [0, 1.5*pDV0], 
xlabel="Quantity", ylabel="$ per unit",line_type=dots,
explicit(pNewGross, q, 0, 1.25*qE), 
explicit(pNewNet, q, 0, 1.25*qE), line_width=2,
line_type=solid, key="Initial Demand", 
explicit(DP(q, a0, ED0), q, 0, 1.25*qE), 
color=black, key = "Tax-laden Demand", 
explicit(DP(q, a0, ED0)/(1 + V0), q, 0, 1.25*qE), 
color = red, key = "Supply",
explicit(SP(q, b0, ES0), q, 0, 1.25*qE) )$